procedure DeplacerDansAnneau(UnAnneau: Anneau; var Arret: TypeArret;
                             Depl: integer);
var i : integer;
    pointeur : Anneau; { pointe normalement sur l'elem. qui serait
                         detruit si Depl=1}
    ALaFin, { sera vrai si on detruit l'elem. en derniere position
              de l'anneau }
    PasFini : boolean;

  procedure Supprime(var Courant : Anneau; var ALaFin: boolean);
  {procedure pour supprimer un element de l'anneau et ajuster le
   pointeur "Courant" en consequence.
   Si on detruit le permier element, ajuste UnAnneau en consequence.
   ALaFin sera vrai si on est en train de detruire le dernier element.
   }
  var temp : Anneau;
  begin {1}
    if Courant^.predecesseur = Courant then begin {2}
      { on detruit l'unique element restant }
      dispose(Courant);
      UnAnneau := nil;
      end {2} { if ... then }
    else begin {3}
      {on efface l'element de l'anneau}
      Courant^.predecesseur^.successeur := Courant^.successeur;
      Courant^.successeur^.predecesseur := Courant^.predecesseur;
      ALaFin := Courant^.successeur=UnAnneau;
      temp := Courant;
      {on ajuste le pointeur}
      Courant := Courant^.successeur;
      {si on detruit le 1er elem., ajuster "UnAnneau" }
      if temp=UnAnneau then UnAnneau := Courant;
      {on efface physiquement l'element}
      dispose(temp);
      end; {3} { if ... else }
  end; {1} { Supprime }

begin {4} { DeplacerDansAnneau }
   PasFini := UnAnneau<>nil;
   Arret := AnneauVide;
   ALaFin := false;
   pointeur := UnAnneau;
   while PasFini do begin {5}
{si le deplacement est nul, on s'arrete}
     if Depl = 0 then begin {6}
       Arret := ElementNul; 
       PasFini := false;
       end {6} { if ... then }
     else if Depl > 0 then begin {7}
{si le deplacement est positif et on est a la fin, on s'arrete }
       if ALaFin then begin {8}
         PasFini := false;
         Arret := SortieAnneau;
         end {8} { if ALaFin then }
       else begin {9}
{si le deplacement est positif}
         i := 1;
         while i < Depl do begin {10}
{on se deplace}
           pointeur := pointeur^.successeur;
{on verifie qu'on sort pas de l'anneau}
           if pointeur = UnAnneau then begin {11}
             Arret := SortieAnneau;
             i := Depl;
             PasFini := false;
             end {11} { if then }
           else i := i+1;
           end; {10} { while }
         end {9} { If ALaFin ... else }
       end {7} { if Depl > 0 }
     else begin {12}
{de meme, pour le cas ou le deplacement est negatif}
       i := 0;
       while i > Depl do begin {13}
{ on veut reculer d'un cran, a moins d'etre au debut }
         if (pointeur=UnAnneau) and not ALaFin then begin {14}
           Arret := SortieAnneau;
           i := Depl;
           PasFini := false;
           end {14} { if }
         else begin {15}
           pointeur := pointeur^.predecesseur;
           i := i-1;
           end; {15} { if ... else }
         end; {13} { while }
       end; {12} { if ... else }
     if PasFini then begin {16}
{on prend la nouvelle valeur pour le deplacement et on l'imprime}
       Depl := pointeur^.Entier;
       writeln(pointeur^.Entier);
{on supprime l'element de l'anneau }
       Supprime(pointeur, ALaFin);
{si l'anneau est vide apres cette suppression, il faudra s'arreter}
       PasFini := pointeur <> nil;
       end; {16} { if PasFini }
     end; {5} { while PasFini }
end; {4} { DeplacerDansAnneau }